Unicode true
ManifestDPIAware true
RequestExecutionLevel user

!include "MUI2.nsh"
!include "LogicLib.nsh"

!define PRODUCT_NAME "Void Bastion"
!define PRODUCT_VERSION "0.1.0-alpha.10"
!define PRODUCT_PUBLISHER "GerGames"
!define PRODUCT_WEBSITE "https://void-bastion.gergames.de/"
!define PRODUCT_EXE "Void-Bastion.exe"

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "..\..\dist\Void-Bastion-Setup-x64.exe"
InstallDir "$LOCALAPPDATA\Programs\Void Bastion"
InstallDirRegKey HKCU "Software\GerGames\Void Bastion" "InstallDir"
SetCompressor /SOLID lzma
SetCompressorDictSize 64
BrandingText "GerGames"
ShowInstDetails show
ShowUninstDetails show

VIProductVersion "0.1.0.10"
VIAddVersionKey /LANG=1031 "ProductName" "${PRODUCT_NAME}"
VIAddVersionKey /LANG=1031 "CompanyName" "${PRODUCT_PUBLISHER}"
VIAddVersionKey /LANG=1031 "FileDescription" "${PRODUCT_NAME} Setup"
VIAddVersionKey /LANG=1031 "FileVersion" "${PRODUCT_VERSION}"
VIAddVersionKey /LANG=1031 "ProductVersion" "${PRODUCT_VERSION}"
VIAddVersionKey /LANG=1031 "LegalCopyright" "Copyright © 2026 Dominic Springer / GerGames"

!define MUI_ABORTWARNING
!define MUI_FINISHPAGE_RUN "$INSTDIR\${PRODUCT_EXE}"
!define MUI_FINISHPAGE_RUN_TEXT "Void Bastion starten"
!define MUI_FINISHPAGE_LINK "Void-Bastion-Website öffnen"
!define MUI_FINISHPAGE_LINK_LOCATION "${PRODUCT_WEBSITE}"

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH

!insertmacro MUI_LANGUAGE "German"
!insertmacro MUI_LANGUAGE "English"

Section "Void Bastion" SEC_MAIN
  SectionIn RO
  SetOutPath "$INSTDIR"
  File "..\..\build\windows\${PRODUCT_EXE}"

  WriteUninstaller "$INSTDIR\Uninstall.exe"
  WriteRegStr HKCU "Software\GerGames\Void Bastion" "InstallDir" "$INSTDIR"

  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "DisplayName" "${PRODUCT_NAME}"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "Publisher" "${PRODUCT_PUBLISHER}"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "URLInfoAbout" "${PRODUCT_WEBSITE}"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "DisplayIcon" "$INSTDIR\${PRODUCT_EXE}"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "UninstallString" '"$INSTDIR\Uninstall.exe"'
  WriteRegDWORD HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "NoModify" 1
  WriteRegDWORD HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion" "NoRepair" 1

  CreateDirectory "$SMPROGRAMS\Void Bastion"
  CreateShortcut "$SMPROGRAMS\Void Bastion\Void Bastion.lnk" "$INSTDIR\${PRODUCT_EXE}"
  CreateShortcut "$SMPROGRAMS\Void Bastion\Void Bastion deinstallieren.lnk" "$INSTDIR\Uninstall.exe"
  CreateShortcut "$DESKTOP\Void Bastion.lnk" "$INSTDIR\${PRODUCT_EXE}"
SectionEnd

Section "Uninstall"
  Delete "$DESKTOP\Void Bastion.lnk"
  Delete "$SMPROGRAMS\Void Bastion\Void Bastion.lnk"
  Delete "$SMPROGRAMS\Void Bastion\Void Bastion deinstallieren.lnk"
  RMDir "$SMPROGRAMS\Void Bastion"

  Delete "$INSTDIR\${PRODUCT_EXE}"
  Delete "$INSTDIR\Uninstall.exe"
  RMDir "$INSTDIR"

  DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Void Bastion"
  DeleteRegKey HKCU "Software\GerGames\Void Bastion"
SectionEnd